SPARQL Examples

SPARQL query editor

To make requests you can use the portal's SPARQL query editor. These kinds of forms assist the developer by providing a text area with syntax highlighting, autocomplete functionality and the option to execute queries, among other features.

Query the graphs available at the SPARQL endpoint

If you do not specify any graph when running the query, information from all available graphs will be returned.

You can list the available graphs with this query:

SELECT DISTINCT ?uri
WHERE { 
  GRAPH ?uri { 
    ?s a ?t 
  } 
}

If we want to know which graph a piece of information belongs to, we can do it like this where variable ?g will show which graph each ?x belongs to:

SELECT DISTINCT ?g ?tipo
WHERE { 
  GRAPH ?g { 
    ?x a ?tipo.
  } 
} 
LIMIT 100

We can get results from a single graph as follows:

SELECT DISTINCT ?tipo
WHERE { 
	GRAPH <http://datos.gob.es/catalogo> { 
		?x a ?tipo. 
  } 
} 
LIMIT 100

Now we will only see the ?x that are in the specified graph.

Retrieve all classes present at the SPARQL endpoint

This query is very useful because it shows all types of information that are stored.

Also, to avoid getting unhelpful noise, we will specify our graphs.

First we specify the Catalog graph:

SELECT DISTINCT ?tipo
WHERE { 
 GRAPH <http://datos.gob.es/catalogo> {
  ?x a ?tipo.
 } 
}

Now we'll use both graphs at once using VALUES

SELECT DISTINCT ?tipo
WHERE { 
  GRAPH ?grafo { 
    ?x a ?tipo.
    }
   VALUES ?grafo {
     <http://datos.gob.es/catalogo> <http://datos.gob.es/nti>
   } 
}

The final result will look similar to the following:

Retrieve all datasets from the Catalog

Now that we know the types, let's request all datasets, which correspond to this URI: http://www.w3.org/ns/dcat#Dataset

PREFIX dcat: <http://www.w3.org/ns/dcat#>
SELECT DISTINCT ?dataset
WHERE {
  ?dataset a dcat:Dataset .
}

The result is a list of URLs for all datasets.

Retrieve all data services from the Catalog

Now that we know the types, let's request all data services, which correspond to this URI: http://www.w3.org/ns/dcat#DataService

PREFIX dcat: <http://www.w3.org/ns/dcat#>
SELECT DISTINCT ?dataService
WHERE {
  ?dataService a dcat:DataService .
}

The result is a list of URLs for all data services.

Get the number of main entities and publishers per Graph

A SPARQL query to quickly overview the content lists the number of resources per type — dcat:Dataset (datasets), dcat:DataService (data services), dcat:Distribution (distributions) and dct:publisher (resource publishers) — for each graph (g) that contains content.

PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX dct:  <http://purl.org/dc/terms/>
SELECT ?g
       (COUNT(DISTINCT ?dataset) AS ?numDatasets)
       (COUNT(DISTINCT ?service) AS ?numDataServices)
       (COUNT(DISTINCT ?distribution) AS ?numDistributions)
       (COUNT(DISTINCT ?publisher) AS ?numPublishers)
WHERE {
  GRAPH ?g {
    ?dataset a dcat:Dataset .
    OPTIONAL { ?dataset dct:publisher ?publisher. }
    OPTIONAL { ?dataset dcat:distribution ?distribution. }
    OPTIONAL { ?service a dcat:DataService. }
  }
}
GROUP BY ?g
ORDER BY DESC(?numDatasets)
LIMIT 100

The result would be:

Retrieve all properties that datasets have

We want to get more information about datasets, but we only know their URIs; let's ask for all their properties:

PREFIX dcat: <http://www.w3.org/ns/dcat#>
SELECT DISTINCT ?propiedad
WHERE {
  ?dataset a dcat:Dataset .
  ?dataset ?propiedad ?valor . 
}

These are some of the properties they have; note that by defining the prefix PREFIX dcat: <http://www.w3.org/ns/dcat#>, the response shows dcat:keyword instead of the full URI http://www.w3.org/ns/dcat#keyword

PREFIX dcat: <http://www.w3.org/ns/dcat#>
SELECT DISTINCT ?propiedad
WHERE {
  ?dataService a dcat:DataService .
  ?dataService ?propiedad ?valor . 
}

PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT DISTINCT ?publicador ?nombre
WHERE {
  ?x a dcat:Dataset ;
     dct:publisher ?publicador .
  ?publicador foaf:name ?nombre.
  FILTER(LANGMATCHES(LANG(?nombre), "es"))
}

Retrieve properties of organizations that publish datasets

With URIs we don't know the organization names; let's ask for the properties of those URIs.

PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX dct: <http://purl.org/dc/terms/>
SELECT DISTINCT ?propiedad
WHERE {
  ?x a dcat:Dataset .
  ?x dct:publisher ?publicador. 
  ?publicador ?propiedad ?valor. 
}

These are all properties of publishers:

Retrieve the names of the ten organizations with the most published datasets and show their counts

To perform this query we need to group results, order them and limit the total to 10.

PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT DISTINCT ?nombre
 (COUNT(?x) AS ?num)
WHERE {
  { ?x a dcat:Dataset } .
  ?x dct:publisher ?publicador .
  ?publicador foaf:name ?nombre
 .
}
GROUP BY ?nombre
 
ORDER BY DESC(?num)
LIMIT 10

The result will be:

PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT DISTINCT ?nombre (COUNT(?x) AS ?num)
WHERE {
  { ?x a dcat:DataService } .
  ?x dct:publisher ?publicador .
  ?publicador foaf:name ?nombre .
}
GROUP BY ?nombre
ORDER BY DESC(?num)
LIMIT 10

PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?nombre 
       (COUNT(DISTINCT ?dataset) AS ?numDatasets)
       (COUNT(DISTINCT ?service) AS ?numDataServices)
       ((COUNT(DISTINCT ?dataset) + COUNT(DISTINCT ?service)) AS ?numTotal)
WHERE {
  ?publicador foaf:name ?nombre .
 
  FILTER(LANGMATCHES(LANG(?nombre), "es"))  
  
  OPTIONAL { ?dataset a dcat:Dataset ; dct:publisher ?publicador . }
  OPTIONAL { ?service a dcat:DataService ; dct:publisher ?publicador . }
  
  FILTER(BOUND(?dataset) || BOUND(?service))
}
GROUP BY ?nombre
ORDER BY DESC(?numTotal)
LIMIT 10